Segédlet BMEGEMMAGM5 “Végeselem módszer alapjai” tárgy laborgyakorlatához.
Készítette: Dr. Kossa Attila, BME Műszaki Mechanikai Tanszék, 2013. szeptember 18.

Kéttámaszú tartó lehajlásának meghatározás a rugalmas szál differenciálegyenletének segítségével.

A statikai egyenletekből következik, hogy az A reakcióerő F-fel egyenlő és lefele mutat, míg a B reakcióerő 2F-fel egyenlő és felfele mutat.

Az 1-es és 2-es szakaszon érvényes hajlítónyomatéki függvények felírása:

Mh1[x]=F*x;
Mh2[x]=F*x-2F(x-(L/2));

A két szakaszra felírva a rugalmas szál differenciálkegyenletét:

rugszaldiff={-w1''[x]==((Mh1[x])/IE),-w2''[x]==((Mh2[x])/IE)};

A peremfeltételek megadása:

peremfelt={w1[0]==0,w1[(L/2)]==0,w2[(L/2)]==0,w1'[(L/2)]==w2'[(L/2)]};

A differenciálegyenlet-rendszer megoldása analitikus úton:

megoldas=DSolve[{rugszaldiff,peremfelt},{w1,w2},x]

Hozzárendelhetjük a megoldásokat (függvényeket) egy új változóhoz:

leh1=First[FullSimplify[w1[x]/.megoldas]]
leh2=First[FullSimplify[w2[x]/.megoldas]]

A kapott lehajlásfüggvények első deriváltja adja a szögelfordulásokat:

szog1=FullSimplify[D[leh1,x]]
szog2=FullSimplify[D[leh2,x]]

Az AB támaszközben a maximális lehajlás helye:

xmax1=Solve[szog1==0,x]

Ebből a megoldásokból a pozitív a keresett megoldás, tehát:

xmax1=xmax1[[2]]

A lehjlás értéke itt:

wmax1=leh1/.xmax1

A feladat paramétereinek numerikus megadása:

L=3;
F=7000;
IE=200000;

Kirajzoltathatjuk mindkét függvény az x=0...L tartományon. Fontos megjegyezni, hogy a w1 csak az x=0...L/2 szakaszon érvényes, míg a w2 az x=L/2...L szakaszon.

Plot[{leh1,leh2},{x,0,L},PlotStyle->{{Red,Thick},{Blue,Thick}}]

Az egyes függvények érvényességi tartomnyának figyelembevételével a kirajzoltatás:

Show[{Plot[leh1,{x,0,(L/2)},PlotStyle->{Red,Thick}],Plot[leh2,{x,(L/2),L},PlotStyle->{Blue,Thick}]},PlotRange->All]

A lehajlás értékeket [m]-ben kell érteni.

A szögelfordulások szemléltetése (rad-ban):

Show[{Plot[szog1,{x,0,(L/2)},PlotStyle->{Red,Thick}],Plot[szog2,{x,(L/2),L},PlotStyle->{Blue,Thick}]},PlotRange->All]

A szögelfordulások szemléltetése (°-ban):

Show[{Plot[szog1/Degree,{x,0,(L/2)},PlotStyle->{Red,Thick}],Plot[szog2/Degree,{x,(L/2),L},PlotStyle->{Blue,Thick}]},PlotRange->All]

Az első szakaszon a lehajlásfüggvény maximumának helye:

x/.xmax1

Numerikusan:

N[x/.xmax1]

Ebben a keresztmetszetben a lehajlás (eltolódás) értéke:

wmax1

Numerikusan:

N[wmax1]